module Cat.Instances.Sets.Complete where

Sets is complete🔗

We prove that the category of $o -sets$ is $(ι, κ) -complete$ for any universe levels $ι \leq o$ and $κ \leq o .$ Inverting this to speak of maxima rather than ordering, to admit all $(ι, κ) -limits,$ we must be in at least the category of $(ι ⊔ κ) -sets,$ but any extra adjustment $o$ is also acceptable. So, suppose we have an indexing category $D$ and a diagram $F : D \to Sets;$ Let’s build a limit for it!

Sets-is-complete : ∀ {ι κ o} → is-complete ι κ (Sets (ι ⊔ κ ⊔ o))
Sets-is-complete {J = D} F = to-limit (to-is-limit lim) module Sets-is-complete where
  module D = Precategory D
  module F = Functor F
  open make-is-limit

Since Set is closed under (arbitrary) products, we can build the limit of an arbitrary diagram $F$ — which we will write $lim F$ — by first taking the product $\prod_{j : D} F (j)$ (which is a set of dependent functions), then restricting ourselves to the subset of those for which $F (g) \circ f (x) = f (y),$ i.e., those which are cones over $F .$

  apex : Set _
  apex = el! $
    Σ[ f ∈ ((j : D.Ob) → ∣ F.₀ j ∣) ]
      (∀ x y (g : D.Hom x y) → F.₁ g (f x) ≡ (f y))

To form a cone, given an object $x : D,$ and an inhabitant $(f, p)$ of the type underlying f-apex, we must cough up (for ψ) an object of $F (x);$ But this is exactly what $f (x)$ gives us. Similarly, since $p$ witnesses that $ψ$ commutes, we can project it directly.

Given some other cone $K,$ to build a cone homomorphism $K \to lim F,$ recall that $K$ comes equipped with its own function $ψ : \prod_{x : D} K \to F (x),$ which we can simply flip around to get a function $K \to \prod_{x : D} F (x);$ This function is in the subset carved out by $lim F$ since $K$ is a cone, hence $F (f) \circ ψ (x) = ψ (y),$ as required.

  -- open Terminal
  lim : make-is-limit F apex
  lim .ψ x (f , p) = f x
  lim .commutes f = funext λ where
    (_ , p) → p _ _ f
  lim .universal eta p x =
    (λ j → eta j x) , λ x y f → p f $ₚ _
  lim .factors _ _ = refl
  lim .unique eta p other q = funext λ x →
    Σ-prop-path! (funext λ j → q j $ₚ x)

Finite set-limits🔗

For expository reasons, we present the computation of the most famous shapes of finite limit (terminal objects, products, pullbacks, and equalisers) in the category of sets. All the definitions below are redundant, since finite limits are always small, and thus the category of sets of any level $ℓ$ admits them.

  Sets-terminal : Terminal (Sets ℓ)
  Sets-terminal .top = el! (Lift _ ⊤)
  Sets-terminal .has⊤ _ = hlevel 0

Products are given by product sets:

  Sets-products : Binary-products (Sets ℓ)
  Sets-products ._⊗₀_ A B = el! (∣ A ∣ × ∣ B ∣)
  Sets-products .π₁ = fst
  Sets-products .π₂ = snd
  Sets-products .⟨_,_⟩ f g x = f x , g x
  Sets-products .π₁∘⟨⟩ = refl
  Sets-products .π₂∘⟨⟩ = refl
  Sets-products .⟨⟩-unique p q i x = p i x , q i x

Equalisers are given by carving out the subset of $A$ where $f$ and $g$ agree using $Σ :$

  Sets-equalisers : Equalisers (Sets ℓ)
  Sets-equalisers .Equ {X} {Y} f g = el! (Σ[ x ∈ X ] (f x ≡ g x))
  Sets-equalisers .equ f g = fst
  Sets-equalisers .equal = funext snd
  Sets-equalisers .equalise e p x = e x , p $ₚ x
  Sets-equalisers .equ∘equalise = refl
  Sets-equalisers .equalise-unique p =
      funext λ x → Σ-prop-path! (p $ₚ x)

Pullbacks are the same, but carving out a subset of $A \times B .$

  Sets-pullbacks : Pullbacks (Sets ℓ)
  Sets-pullbacks .Pb {X} {Y} {Z} f g = el! (Σ[ x ∈ X ] Σ[ y ∈ Y ] (f x ≡ g y))
  Sets-pullbacks .p₁ f g (x , _ , _) = x
  Sets-pullbacks .p₂ f g (_ , y , _) = y
  Sets-pullbacks .square = funext (snd ⊙ snd)
  Sets-pullbacks .pb p1 p2 sq x = p1 x , p2 x , sq $ₚ x
  Sets-pullbacks .p₁∘pb = refl
  Sets-pullbacks .p₂∘pb = refl
  Sets-pullbacks .pb-unique p q =
    funext λ x → Σ-pathp (p $ₚ x) (Σ-pathp (q $ₚ x) prop!)

Hence, Sets is finitely complete:

  open Finitely-complete

  Sets-finitely-complete : Finitely-complete (Sets ℓ)
  Sets-finitely-complete .terminal = Sets-terminal
  Sets-finitely-complete .products = Sets-products
  Sets-finitely-complete .equalisers = Sets-equalisers
  Sets-finitely-complete .pullbacks = Sets-pullbacks