module Cat.Displayed.Instances.Subobjects
  {o ℓ} (B : Precategory o ℓ)
  where

The fibration of subobjects🔗

Given a base category $B,$ we can define the displayed category of subobjects over $B .$ This is, in essence, a restriction of the codomain fibration of $B,$ but with our attention restricted to the monomorphisms $a ↪ b$ rather than arbitrary maps $a \to b .$

record Subobject (y : Ob) : Type (o ⊔ ℓ) where
  no-eta-equality
  field
    {domain} : Ob
    map   : Hom domain y
    monic : is-monic map

open Subobject public

To make formalisation smoother, we define our own version of displayed morphisms in the subobject fibration, rather than reusing those of the fundamental self-indexing. The reason for this is quite technical: the type of maps in the self-indexing is only dependent (the domains and) the morphisms being considered, meaning nothing constrains the proofs that these are monomorphisms, causing unification to fail at the determining the full Subobjects involved.

record ≤-over {x y} (f : Hom x y) (a : Subobject x) (b : Subobject y) : Type ℓ where
  no-eta-equality
  field
    map : Hom (a .domain) (b .domain)
    sq : f ∘ Subobject.map a ≡ Subobject.map b ∘ map

open ≤-over public

We will denote the type of maps $x^{'} \to_{f} y^{'}$ in the subobject fibration by $x^{'} \leq_{f} y^{'},$ since there is at most one such map: if $g, h$ satisfy $y^{'} g = f x^{'} = y^{'} h,$ then, since $y^{'}$ is a mono, $g = h .$

Setting up the displayed category is now nothing more than routine verification: the identity map satisfies $id a = a id,$ and commutative squares can be pasted together.

Subobjects : Displayed B (o ⊔ ℓ) ℓ
Subobjects .Ob[_] y = Subobject y
Subobjects .Hom[_]  = ≤-over
Subobjects .Hom[_]-set f a b = hlevel 2

Subobjects .id' .map = id
Subobjects .id' .sq  = id-comm-sym

Subobjects ._∘'_ α β .map = α .map ∘ β .map
Subobjects ._∘'_ α β .sq  = pullr (β .sq) ∙ extendl (α .sq)

As a fibration🔗

By exactly the same construction as for the fundamental self-indexing, if $B$ has pullbacks, the displayed category we have built is actually a fibration. The construction is slightly simpler now that we have no need to worry about uniqueness, but we can remind ourselves of the universal property:

On the first stage, we are given the data in black: we can complete an open span $y^{'} ↪ y f x$ to a Cartesian square (in blue) by pulling $y^{'}$ back along $f;$ this base change remains a monomorphism. Now given the data in red, we verify that the dashed arrow exists, which is enough for its uniqueness.

Subobject-fibration
  : Pullbacks B
  → Cartesian-fibration Subobjects
Subobject-fibration pullbacks .has-lift f y' = l where
  open Pullbacks pullbacks

  l : Cartesian-lift Subobjects f y'

  -- The blue square:
  l .x' .domain = Pb (y' .map) f
  l .x' .map    = p₂ (y' .map) f
  l .x' .monic  = is-monic→pullback-is-monic (y' .monic) has-is-pb
  -- (it .has-is-pb)
  l .lifting .map = p₁ (y' .map) f
  l .lifting .sq  = sym square

  -- The dashed red arrow:
  l .cartesian .universal {u' = u'} m h' = λ where
    .map → pb (h' .map) (m ∘ u' .map) (sym (h' .sq) ∙ sym (assoc f m (u' .map)))
    .sq  → sym p₂∘pb
  l .cartesian .commutes _ _ = prop!
  l .cartesian .unique _ _   = prop!

As a (weak) cocartesian fibration🔗

If $B$ has an image factorisation for every morphism, then its fibration of subobjects is a weak cocartesian fibration. By a general fact, if $B$ also has pullbacks, then $Sub (-)$ is a cocartesian fibration.

Subobject-weak-opfibration
  : (∀ {x y} (f : Hom x y) → Image B f)
  → is-weak-cocartesian-fibration Subobjects
Subobject-weak-opfibration ims .weak-lift f x' = l where
  module im = Image B (ims (f ∘ x' .map))

To understand this result, we remind ourselves of the universal property of an image factorisation for $f : a \to b :$ It is the initial subobject through with $f$ factors. That is to say, if $m : Sub (b)$ is another subobject, and $f = m e$ for some map $e : a \to m,$ then $m \leq im f .$ Summarised diagrammatically, the universal property of an image factorisation looks like a kite:

Now compare this with the universal property required of a weak co-cartesian lift:

By smooshing the corner $x^{'} ↪ x \to y$ together (i.e., composing $x^{'}$ and $f),$ we see that this is exactly the kite-shaped universal property of $im f x^{'} .$

  l : Weak-cocartesian-lift Subobjects f x'
  l .y' .domain = im.Im
  l .y' .map    = im.Im→codomain
  l .y' .monic  = im.Im→codomain-is-M

  l .lifting .map = im.corestrict
  l .lifting .sq  = sym im.image-factors

  l .weak-cocartesian .universal {x' = y'} h .map = im.universal _ (y' .monic) (h .map) (sym (h .sq))
  l .weak-cocartesian .universal h .sq = idl _ ∙ sym im.universal-factors

  l .weak-cocartesian .commutes g' = prop!
  l .weak-cocartesian .unique _ _  = prop!

The aforementioned general fact says that any cartesian and weak cocartesian fibration must actually be a full opfibration.

Subobject-opfibration
  : (∀ {x y} (f : Hom x y) → Image B f)
  → (pb : Pullbacks B)
  → Cocartesian-fibration Subobjects
Subobject-opfibration images pb = cartesian+weak-opfibration→opfibration _
  (Subobject-fibration pb)
  (Subobject-weak-opfibration images)

Subobjects over a base🔗

We define the category $Sub (y)$ of subobjects of $y$ as a fibre of the subobject fibration. However, we use a purpose-built transport function to cut down on the number of coherences required to work with $Sub (y)$ at use-sites.

Sub : Ob → Precategory (o ⊔ ℓ) ℓ
Sub y = Fibre' Subobjects y re coh where
  re : ∀ {a b} → ≤-over (id ∘ id) a b → ≤-over id a b
  re x .map = x .map
  re x .sq  = ap₂ _∘_ (introl refl) refl ∙ x .sq

  abstract
    coh : ∀ {a b} (f : ≤-over (id ∘ id) a b) → re f ≡ transport (λ i → ≤-over (idl id i) a b) f
    coh f = prop!

module Sub {y} = Cr (Sub y)

Fibrewise cartesian structure🔗

Since products in slice categories are given by pullbacks, and pullbacks preserve monomorphisms, if $B$ has pullbacks, then $Sub (y)$ has products, regardless of what $y$ is.

Sub-products
  : ∀ {y}
  → Pullbacks B
  → Binary-products (Sub y)
Sub-products {y} pullbacks = prods where
  open Pullbacks pullbacks
  open Binary-products

  prods : Binary-products (Sub y)
  (prods ⊗₀ a) b .domain = Pb (a .map) (b .map)
  (prods ⊗₀ a) b .map = a .map ∘ p₁ (a .map) (b .map)
  (prods ⊗₀ a) b .monic = monic-∘
    (a .monic)
    (is-monic→pullback-is-monic (b .monic) (rotate-pullback has-is-pb))
  prods .π₁ .map = p₁ _ _
  prods .π₁ .sq = idl _
  prods .π₂ .map = p₂ _ _
  prods .π₂ .sq = idl _ ∙ square
  prods .⟨_,_⟩ q≤a q≤b .map = pb (q≤a .map) (q≤b .map) (sym (q≤a .sq) ∙ q≤b .sq)
  prods .⟨_,_⟩ q≤a q≤b .sq =
      idl _ ∙ sym (pullr p₁∘pb ∙ sym (q≤a .sq) ∙ idl _)
  prods .π₁∘⟨⟩ = prop!
  prods .π₂∘⟨⟩ = prop!
  prods .⟨⟩-unique _ _ = prop!

Univalence🔗

Since identity of $m, n : Sub (y)$ is given by identity of they underlying objects and identity-over of the corresponding morphisms, if $B$ is univalent, we can conclude that $Sub (y)$ is, too. Since $Sub (y)$ is always thin, we can summarise the situation by saying that $Sub (y)$ is a partial order if $B$ is univalent.

Sub-is-category : ∀ {y} → is-category B → is-category (Sub y)
Sub-is-category b-cat .to-path {a} {b} x =
  Sub-path
    (b-cat .to-path i)
    (Univalent.Hom-pathp-refll-iso b-cat (sym (x .Sub.from .sq) ∙ idl _))
  where
    i : a .domain ≅ b .domain
    i = make-iso (x .Sub.to .map) (x .Sub.from .map) (ap map (Sub.invl x)) (ap map (Sub.invr x))
Sub-is-category b-cat .to-path-over p =
  Sub.≅-pathp refl _ prop!