module Cat.Diagram.Biproduct where

Biproducts🔗

Recall that, in an $Ab$ -enriched category, products and coproducts automatically coincide: these are called biproducts and are written $A \oplus B .$

Following (Karvonen 2020), we can define what it means to be a biproduct in a general category: we say that a diagram like the one above is a biproduct diagram if $(A \oplus B, π_{1}, π_{2})$ is a product diagram, $(A \oplus B, ι_{1}, ι_{2})$ is a coproduct diagram, and the following equations relating the product projections and coproduct injections hold:

π_{1} \circ ι_{1} π_{2} \circ ι_{2} ι_{1} \circ π_{1} \circ ι_{2} \circ π_{2} \equiv id_{A} \equiv id_{B} \equiv ι_{2} \circ π_{2} \circ ι_{1} \circ π_{1}

  record is-biproduct {A B P}
    (π₁ : Hom P A) (π₂ : Hom P B)
    (ι₁ : Hom A P) (ι₂ : Hom B P)
    : Type (o ⊔ ℓ) where
    field
      has-is-product   : is-product C π₁ π₂
      has-is-coproduct : is-coproduct C ι₁ ι₂
      πι₁ : π₁ ∘ ι₁ ≡ id
      πι₂ : π₂ ∘ ι₂ ≡ id
      ιπ-comm : ι₁ ∘ π₁ ∘ ι₂ ∘ π₂ ≡ ι₂ ∘ π₂ ∘ ι₁ ∘ π₁

  record Biproduct (A B : Ob) : Type (o ⊔ ℓ) where
    field
      biapex : Ob
      π₁ : Hom biapex A
      π₂ : Hom biapex B
      ι₁ : Hom A biapex
      ι₂ : Hom B biapex
      has-is-biproduct : is-biproduct π₁ π₂ ι₁ ι₂

Categories with all biproducts🔗

  record Binary-biproducts : Type (o ⊔ ℓ) where
    no-eta-equality
    field
      _⊕₀_ : Ob → Ob → Ob

      π₁ : ∀ {A B} → Hom (A ⊕₀ B) A
      π₂ : ∀ {A B} → Hom (A ⊕₀ B) B
      ⟨_,_⟩ : ∀ {X A B} (p1 : Hom X A) (p2 : Hom X B) → Hom X (A ⊕₀ B)
      π₁∘⟨⟩ : ∀ {X A B} {p1 : Hom X A} {p2 : Hom X B} → π₁ ∘ ⟨ p1 , p2 ⟩ ≡ p1
      π₂∘⟨⟩ : ∀ {X A B} {p1 : Hom X A} {p2 : Hom X B} → π₂ ∘ ⟨ p1 , p2 ⟩ ≡ p2
      ⟨⟩-unique
        : ∀ {X A B} {p1 : Hom X A} {p2 : Hom X B}
        → {other : Hom X (A ⊕₀ B)}
        → π₁ ∘ other ≡ p1
        → π₂ ∘ other ≡ p2
        → other ≡ ⟨ p1 , p2 ⟩

      ι₁ : ∀ {A B} → Hom A (A ⊕₀ B)
      ι₂ : ∀ {A B} → Hom B (A ⊕₀ B)
      [_,_] : ∀ {A B X} (inj0 : Hom A X) (inj1 : Hom B X) → Hom (A ⊕₀ B) X
      []∘ι₁ : ∀ {A B X} {inj0 : Hom A X} {inj1 : Hom B X} → [ inj0 , inj1 ] ∘ ι₁ ≡ inj0
      []∘ι₂ : ∀ {A B X} {inj0 : Hom A X} {inj1 : Hom B X} → [ inj0 , inj1 ] ∘ ι₂ ≡ inj1
      []-unique
        : ∀ {A B X} {inj0 : Hom A X} {inj1 : Hom B X}
        → {other : Hom (A ⊕₀ B) X}
        → other ∘ ι₁ ≡ inj0
        → other ∘ ι₂ ≡ inj1
        → other ≡ [ inj0 , inj1 ]

      πι₁ : ∀ {A B} → π₁ ∘ ι₁ {A} {B} ≡ id
      πι₂ : ∀ {A B} → π₂ ∘ ι₂ {A} {B} ≡ id
      ιπ-comm : ∀ {A B} → ι₁ {A} {B} ∘ π₁ ∘ ι₂ ∘ π₂ {A} {B} ≡ ι₂ ∘ π₂ ∘ ι₁ ∘ π₁

Semiadditive categories🔗

Just like terminal objects (resp. initial objects) are 0-ary products (resp. coproducts), zero objects are 0-ary biproducts. A category with a zero object and binary biproducts (hence all finite biproducts) is called semiadditive.

  record is-semiadditive : Type (o ⊔ ℓ) where
    field
      has-zero : Zero C
      has-biproducts : Binary-biproducts

As the name hints, every additive category is semiadditive. However, quite surprisingly, it turns out that the structure¹ of a semiadditive category is already enough to define an enrichment of $C$ in commutative monoids!

We define the addition of morphisms $f + g : A \to B$ by the following diagram, where $δ$ (resp. $\nabla)$ is the diagonal map (resp. codiagonal map).

    _+→_ : ∀ {x y} → Hom x y → Hom x y → Hom x y
    f +→ g = ∇ ∘ (f ⊗₁ g) ∘ δ

We start by noticing a few properties of finite biproducts. First, while we are of course justified in writing $A \oplus B$ without ambiguity for objects, we must prove that $f \times_{1} g \equiv f +_{1} g$ so that we can write $f \oplus g$ without ambiguity for morphisms.

To that end, we start by showing that $π_{1} \circ ι_{2}$ and $π_{2} \circ ι_{1}$ are zero morphisms.

    π₁-ι₂ : ∀ {a b} → π₁ {a} {b} ∘ ι₂ ≡ zero→
    π₂-ι₁ : ∀ {a b} → π₂ {a} {b} ∘ ι₁ ≡ zero→

The proofs follow (Karvonen 2020) and are unenlightening.

    π₁-ι₂ = zero-unique λ f g →
      let h = ⟨ π₁ ∘ ι₂ ∘ g , f ⟩ in
      (π₁ ∘ ι₂) ∘ f                   ≡⟨ insertl πι₁ ⟩
      π₁ ∘ ι₁ ∘ (π₁ ∘ ι₂) ∘ f         ≡˘⟨ refl⟩∘⟨ refl⟩∘⟨ assoc _ _ _ ∙ (refl⟩∘⟨ π₂∘⟨⟩) ⟩
      π₁ ∘ ι₁ ∘ π₁ ∘ ι₂ ∘ π₂ ∘ h      ≡⟨ refl⟩∘⟨ pulll4 ιπ-comm ⟩
      π₁ ∘ (ι₂ ∘ π₂ ∘ ι₁ ∘ π₁) ∘ h    ≡⟨ refl⟩∘⟨ pullr (pullr (pullr π₁∘⟨⟩)) ⟩
      π₁ ∘ ι₂ ∘ π₂ ∘ ι₁ ∘ π₁ ∘ ι₂ ∘ g ≡˘⟨ refl⟩∘⟨ extendl4 ιπ-comm ⟩
      π₁ ∘ ι₁ ∘ π₁ ∘ ι₂ ∘ π₂ ∘ ι₂ ∘ g ≡⟨ cancell πι₁ ⟩
      π₁ ∘ ι₂ ∘ π₂ ∘ ι₂ ∘ g           ≡⟨ pushr (refl⟩∘⟨ cancell πι₂) ⟩
      (π₁ ∘ ι₂) ∘ g                   ∎

    π₂-ι₁ = zero-unique λ f g →
      let h = ⟨ f , π₂ ∘ ι₁ ∘ g ⟩ in
      (π₂ ∘ ι₁) ∘ f                   ≡⟨ insertl πι₂ ⟩
      π₂ ∘ ι₂ ∘ (π₂ ∘ ι₁) ∘ f         ≡˘⟨ refl⟩∘⟨ refl⟩∘⟨ assoc _ _ _ ∙ (refl⟩∘⟨ π₁∘⟨⟩) ⟩
      π₂ ∘ ι₂ ∘ π₂ ∘ ι₁ ∘ π₁ ∘ h      ≡˘⟨ refl⟩∘⟨ pushl4 ιπ-comm ⟩
      π₂ ∘ (ι₁ ∘ π₁ ∘ ι₂ ∘ π₂) ∘ h    ≡⟨ refl⟩∘⟨ pullr (pullr (pullr π₂∘⟨⟩)) ⟩
      π₂ ∘ ι₁ ∘ π₁ ∘ ι₂ ∘ π₂ ∘ ι₁ ∘ g ≡⟨ refl⟩∘⟨ extendl4 ιπ-comm ⟩
      π₂ ∘ ι₂ ∘ π₂ ∘ ι₁ ∘ π₁ ∘ ι₁ ∘ g ≡⟨ cancell πι₂ ⟩
      π₂ ∘ ι₁ ∘ π₁ ∘ ι₁ ∘ g           ≡⟨ pushr (refl⟩∘⟨ cancell πι₁) ⟩
      (π₂ ∘ ι₁) ∘ g                   ∎

Next, we note that maps $f : A \oplus B \to C \oplus D$ are uniquely determined, thanks to the universal properties of the product and coproduct, by the four components $π_{i} \circ f \circ ι_{j}$ for $i, j : {1, 2} .$ In other words, $f$ admits a unique matrix representation

[f_{11} f_{21} f_{12} f_{22}]

    unique-matrix
      : ∀ {a b c d} {f g : Hom (a ⊕₀ b) (c ⊕₀ d)}
      → (π₁ ∘ f ∘ ι₁ ≡ π₁ ∘ g ∘ ι₁)
      → (π₂ ∘ f ∘ ι₁ ≡ π₂ ∘ g ∘ ι₁)
      → (π₁ ∘ f ∘ ι₂ ≡ π₁ ∘ g ∘ ι₂)
      → (π₂ ∘ f ∘ ι₂ ≡ π₂ ∘ g ∘ ι₂)
      → f ≡ g
    unique-matrix p₁₁ p₁₂ p₂₁ p₂₂ = []-unique₂
      (⟨⟩-unique₂ p₁₁ p₁₂ refl refl)
      (⟨⟩-unique₂ p₂₁ p₂₂ refl refl)
      refl refl

This implies that $f \times_{1} g$ and $f +_{1} g$ are equal, as they both have the same matrix representation:

[id 0 0 id]

    ⊕₁≡⊗₁ : ∀ {a b c d} {f : Hom a b} {g : Hom c d} → f ⊕₁ g ≡ f ⊗₁ g
    ⊕₁≡⊗₁ = unique-matrix
      ((refl⟩∘⟨ []∘ι₁) ∙ cancell πι₁ ∙ sym (pulll π₁∘⟨⟩ ∙ cancelr πι₁))
      ((refl⟩∘⟨ []∘ι₁) ∙ pulll π₂-ι₁ ∙ zero-∘r _ ∙ sym (pulll π₂∘⟨⟩ ∙ pullr π₂-ι₁ ∙ zero-∘l _))
      ((refl⟩∘⟨ []∘ι₂) ∙ pulll π₁-ι₂ ∙ zero-∘r _ ∙ sym (pulll π₁∘⟨⟩ ∙ pullr π₁-ι₂ ∙ zero-∘l _))
      ((refl⟩∘⟨ []∘ι₂) ∙ cancell πι₂ ∙ sym (pulll π₂∘⟨⟩ ∙ cancelr πι₂))

Similarly, we show that the associators and braidings for products and coproducts coincide.

    coassoc≡assoc : ∀ {a b c} → ⊕-assoc {a} {b} {c} ≡ ×-assoc
    coswap≡swap : ∀ {a b} → coswap {a} {b} ≡ swap

    coassoc≡assoc = unique-matrix
      ((refl⟩∘⟨ []∘ι₁) ∙ cancell πι₁ ∙ sym (pulll π₁∘⟨⟩ ∙ ⟨⟩-unique₂
        (pulll π₁∘⟨⟩ ∙ πι₁)
        (pulll π₂∘⟨⟩ ∙ pullr π₂-ι₁ ∙ zero-∘l _)
        πι₁ π₂-ι₁))
      ((refl⟩∘⟨ []∘ι₁) ∙ pulll π₂-ι₁ ∙ zero-∘r _ ∙ sym (pulll π₂∘⟨⟩ ∙ pullr π₂-ι₁ ∙ zero-∘l _))
      ((refl⟩∘⟨ []∘ι₂) ∙ unique-matrix
        ((refl⟩∘⟨ pullr []∘ι₁ ∙ cancell πι₁) ∙ π₁-ι₂ ∙ sym (pulll (pulll π₁∘⟨⟩) ∙ (π₁-ι₂ ⟩∘⟨refl) ∙ zero-∘r _))
        ((refl⟩∘⟨ pullr []∘ι₁ ∙ cancell πι₁) ∙ πι₂ ∙ sym (pulll (pulll π₂∘⟨⟩) ∙ (cancelr πι₂ ⟩∘⟨refl) ∙ πι₁))
        ((refl⟩∘⟨ pullr []∘ι₂ ∙ π₁-ι₂) ∙ zero-∘l _ ∙ sym (pulll (pulll π₁∘⟨⟩) ∙ (π₁-ι₂ ⟩∘⟨refl) ∙ zero-∘r _))
        ((refl⟩∘⟨ pullr []∘ι₂ ∙ π₁-ι₂) ∙ zero-∘l _ ∙ sym (pulll (pulll π₂∘⟨⟩) ∙ (cancelr πι₂ ⟩∘⟨refl) ∙ π₁-ι₂))
      ∙ sym (pulll π₁∘⟨⟩))
      ((refl⟩∘⟨ []∘ι₂) ∙ []-unique₂
        (pullr []∘ι₁ ∙ pulll π₂-ι₁ ∙ zero-∘r _)
        (pullr []∘ι₂ ∙ πι₂)
        ((cancelr πι₂ ⟩∘⟨refl) ∙ π₂-ι₁)
        ((cancelr πι₂ ⟩∘⟨refl) ∙ πι₂)
      ∙ sym (pulll π₂∘⟨⟩))

    coswap≡swap = ⟨⟩-unique
      ([]-unique₂
        (pullr []∘ι₁ ∙ π₁-ι₂) (pullr []∘ι₂ ∙ πι₁)
        π₂-ι₁ πι₂)
      ([]-unique₂
        (pullr []∘ι₁ ∙ πι₂) (pullr []∘ι₂ ∙ π₂-ι₁)
        πι₁ π₁-ι₂)

We are finally ready to show that addition of morphisms is associative, commutative and unital. These properties essentially follow from the corresponding properties of biproducts. For associativity, we use the following diagram:

    +-assoc : ∀ {x y} {f g h : Hom x y} → f +→ (g +→ h) ≡ (f +→ g) +→ h
    +-assoc {f = f} {g} {h} =
      ∇ ∘ (f ⊗₁ (∇ ∘ (g ⊗₁ h) ∘ δ)) ∘ δ                           ≡˘⟨ refl⟩∘⟨ ⊗.pulll3 (idl _ ∙ idr _ ,ₚ refl) ⟩
      ∇ ∘ (id ⊗₁ ∇) ∘ (f ⊗₁ (g ⊗₁ h)) ∘ (id ⊗₁ δ) ∘ δ             ≡˘⟨ refl⟩∘⟨ ⊕₁≡⊗₁ ⟩∘⟨refl ⟩
      ∇ ∘ (id ⊕₁ ∇) ∘ (f ⊗₁ (g ⊗₁ h)) ∘ (id ⊗₁ δ) ∘ δ             ≡˘⟨ pushl ∇-assoc ⟩
      (∇ ∘ (∇ ⊕₁ id) ∘ ⊕-assoc) ∘ (f ⊗₁ (g ⊗₁ h)) ∘ (id ⊗₁ δ) ∘ δ ≡⟨ (refl⟩∘⟨ ⊕₁≡⊗₁ ⟩∘⟨refl) ⟩∘⟨refl ⟩
      (∇ ∘ (∇ ⊗₁ id) ∘ ⊕-assoc) ∘ (f ⊗₁ (g ⊗₁ h)) ∘ (id ⊗₁ δ) ∘ δ ≡⟨ pullr (pullr (coassoc≡assoc ⟩∘⟨refl)) ⟩
      ∇ ∘ (∇ ⊗₁ id) ∘ ×-assoc ∘ (f ⊗₁ (g ⊗₁ h)) ∘ (id ⊗₁ δ) ∘ δ   ≡⟨ refl⟩∘⟨ refl⟩∘⟨ extendl (associator .Isoⁿ.from .is-natural _ _ _) ⟩
      ∇ ∘ (∇ ⊗₁ id) ∘ ((f ⊗₁ g) ⊗₁ h) ∘ ×-assoc ∘ (id ⊗₁ δ) ∘ δ   ≡⟨ refl⟩∘⟨ refl⟩∘⟨ refl⟩∘⟨ assoc-δ ⟩
      ∇ ∘ (∇ ⊗₁ id) ∘ ((f ⊗₁ g) ⊗₁ h) ∘ (δ ⊗₁ id) ∘ δ             ≡⟨ refl⟩∘⟨ ⊗.pulll3 (refl ,ₚ idl _ ∙ idr _) ⟩
      ∇ ∘ ((∇ ∘ (f ⊗₁ g) ∘ δ) ⊗₁ h) ∘ δ                           ∎

Commutativity follows from the following diagram, where $β$ is the braiding:

    +-comm : ∀ {x y} {f g : Hom x y} → f +→ g ≡ g +→ f
    +-comm {f = f} {g} =
      ∇ ∘ (f ⊗₁ g) ∘ δ          ≡˘⟨ pulll ∇-coswap ⟩
      ∇ ∘ coswap ∘ (f ⊗₁ g) ∘ δ ≡⟨ refl⟩∘⟨ coswap≡swap ⟩∘⟨refl ⟩
      ∇ ∘ swap ∘ (f ⊗₁ g) ∘ δ   ≡˘⟨ refl⟩∘⟨ extendl (swap-natural _) ⟩
      ∇ ∘ (g ⊗₁ f) ∘ swap ∘ δ   ≡⟨ refl⟩∘⟨ refl⟩∘⟨ swap-δ ⟩
      ∇ ∘ (g ⊗₁ f) ∘ δ          ∎

Since addition is commutative, it suffices to show that the zero morphism is a left unit. We again use the analogous property of biproducts, which is that the zero object is a left unit for $\oplus .$

    ∇-¡l : ∀ {a} → ∇ {a} ∘ (¡ ⊕₁ id) ≡ π₂
    ∇-¡l = []-unique₂
      (¡-unique₂ _ _) (pullr []∘ι₂ ∙ cancell []∘ι₂)
      refl πι₂

    +-idl : ∀ {x y} {f : Hom x y} → zero→ +→ f ≡ f
    +-idl {f = f} =
      ∇ ∘ (zero→ ⊗₁ f) ∘ δ         ≡⟨ refl⟩∘⟨ ⊗.pushl (refl ,ₚ sym (idl _)) ⟩
      ∇ ∘ (¡ ⊗₁ id) ∘ (! ⊗₁ f) ∘ δ ≡˘⟨ refl⟩∘⟨ ⊕₁≡⊗₁ ⟩∘⟨refl ⟩
      ∇ ∘ (¡ ⊕₁ id) ∘ (! ⊗₁ f) ∘ δ ≡⟨ pulll ∇-¡l ⟩
      π₂ ∘ (! ⊗₁ f) ∘ δ            ≡⟨ pulll π₂∘⟨⟩ ⟩
      (f ∘ π₂) ∘ δ                 ≡⟨ cancelr π₂∘⟨⟩ ⟩
      f                            ∎

    +-idr : ∀ {x y} {f : Hom x y} → f +→ zero→ ≡ f
    +-idr = +-comm ∙ +-idl

Naturality of the (co)diagonals implies that composition is bilinear with respect to our defined addition.

    ∘-linear-l
      : ∀ {a b c} {f g : Hom b c} {h : Hom a b}
      → f ∘ h +→ g ∘ h ≡ (f +→ g) ∘ h
    ∘-linear-l {f = f} {g} {h} =
      ∇ ∘ ((f ∘ h) ⊗₁ (g ∘ h)) ∘ δ ≡⟨ refl⟩∘⟨ ⊗.pushl refl ⟩
      ∇ ∘ (f ⊗₁ g) ∘ (h ⊗₁ h) ∘ δ  ≡˘⟨ pullr (pullr (δ-natural _ _ _)) ⟩
      (∇ ∘ (f ⊗₁ g) ∘ δ) ∘ h       ∎

    ∘-linear-r
      : ∀ {a b c} {f g : Hom a b} {h : Hom b c}
      → h ∘ f +→ h ∘ g ≡ h ∘ (f +→ g)
    ∘-linear-r {f = f} {g} {h} =
      ∇ ∘ ((h ∘ f) ⊗₁ (h ∘ g)) ∘ δ ≡⟨ refl⟩∘⟨ ⊗.pushl refl ⟩
      ∇ ∘ (h ⊗₁ h) ∘ (f ⊗₁ g) ∘ δ  ≡˘⟨ refl⟩∘⟨ ⊕₁≡⊗₁ ⟩∘⟨refl ⟩
      ∇ ∘ (h ⊕₁ h) ∘ (f ⊗₁ g) ∘ δ  ≡⟨ extendl (∇-natural _ _ _) ⟩
      h ∘ ∇ ∘ (f ⊗₁ g) ∘ δ         ∎

This provides an alternative route to defining additive categories: instead of starting with an $Ab$ -enriched category and requiring finite (co)products, we can start with a semiadditive category and require that every $Hom -monoid$ be a group.

In order to construct a semiadditive category from a category with a zero object, binary products and coproducts, it suffices to require that the map $A + B \to A \times B$ defined by the matrix representation

[id 0 0 id]

is invertible.

  record make-semiadditive : Type (o ⊔ ℓ) where
    field
      has-zero : Zero C
      has-coprods : Binary-coproducts C
      has-prods : Binary-products C

    open Zero has-zero
    open Binary-products has-prods
    open Binary-coproducts has-coprods

    coproduct→product : ∀ {a b} → Hom (a ⊕₀ b) (a ⊗₀ b)
    coproduct→product = ⟨ [ id , zero→ ]
                        , [ zero→ , id ] ⟩

    field
      coproduct≅product : ∀ {a b} → is-invertible (coproduct→product {a} {b})

If that is the case, then the coproduct $A + B$ is a biproduct when equipped with the projections $[id, 0]$ and $[0, id] .$

    ⊕-is-product : ∀ {A B} → is-product C [ id {A} , zero→ ] [ zero→ , id {B} ]
    ⊕-is-product = is-product-iso-apex coproduct≅product π₁∘⟨⟩ π₂∘⟨⟩ has-is-product

    private module ⊕-is-product {A} {B} = is-product (⊕-is-product {A} {B})

    has-biproducts : Binary-biproducts
    has-biproducts .Binary-biproducts._⊕₀_ = _⊕₀_
    has-biproducts .Binary-biproducts.π₁ = [ id , zero→ ]
    has-biproducts .Binary-biproducts.π₂ = [ zero→ , id ]
    has-biproducts .Binary-biproducts.⟨_,_⟩ = ⊕-is-product.⟨_,_⟩
    has-biproducts .Binary-biproducts.π₁∘⟨⟩ = ⊕-is-product.π₁∘⟨⟩
    has-biproducts .Binary-biproducts.π₂∘⟨⟩ = ⊕-is-product.π₂∘⟨⟩
    has-biproducts .Binary-biproducts.⟨⟩-unique = ⊕-is-product.unique
    has-biproducts .Binary-biproducts.ι₁ = ι₁
    has-biproducts .Binary-biproducts.ι₂ = ι₂
    has-biproducts .Binary-biproducts.[_,_] = [_,_]
    has-biproducts .Binary-biproducts.[]∘ι₁ = []∘ι₁
    has-biproducts .Binary-biproducts.[]∘ι₂ = []∘ι₂
    has-biproducts .Binary-biproducts.[]-unique = []-unique
    has-biproducts .Binary-biproducts.πι₁ = []∘ι₁
    has-biproducts .Binary-biproducts.πι₂ = []∘ι₂
    has-biproducts .Binary-biproducts.ιπ-comm =
      ι₁ ∘ [ id , zero→ ] ∘ ι₂ ∘ [ zero→ , id ] ≡⟨ refl⟩∘⟨ pulll []∘ι₂ ⟩
      ι₁ ∘ zero→ ∘ [ zero→ , id ]               ≡⟨ pulll (zero-∘l _) ∙ zero-∘r _ ⟩
      zero→                                     ≡˘⟨ pulll (zero-∘l _) ∙ zero-∘r _ ⟩
      ι₂ ∘ zero→ ∘ [ id , zero→ ]               ≡˘⟨ refl⟩∘⟨ pulll []∘ι₁ ⟩
      ι₂ ∘ [ zero→ , id ] ∘ ι₁ ∘ [ id , zero→ ] ∎

  open make-semiadditive

  to-semiadditive : make-semiadditive → is-semiadditive
  to-semiadditive mk .is-semiadditive.has-zero = has-zero mk
  to-semiadditive mk .is-semiadditive.has-biproducts = has-biproducts mk

Really property, in a univalent category.↩︎

References

Karvonen, Martti. 2020. “Biproducts Without Pointedness.” https://arxiv.org/abs/1801.06488.