module Cat.Diagram.Monad where

Monads🔗

A monad on a category $C$ is one way of categorifying the concept of monoid. Specifically, rather than living in a monoidal category, a monad lives in a bicategory. Here, we concern ourselves with the case of monads in the bicategory of categories, so that we may say: A monad is an endofunctor $M,$ equipped with a unit natural transformation $Id \Rightarrow M,$ and a multiplication $(M \circ M) \Rightarrow M .$

  record Monad : Type (o ⊔ h) where
    no-eta-equality
    field
      M    : Functor C C
      unit : Id => M
      mult : (M F∘ M) => M

Furthermore, these natural transformations must satisfy identity and associativity laws exactly analogous to those of a monoid.

    field
      left-ident  : ∀ {x} → μ x C.∘ M₁ (η x) ≡ C.id
      right-ident : ∀ {x} → μ x C.∘ η (M₀ x) ≡ C.id
      mult-assoc  : ∀ {x} → μ x C.∘ M₁ (μ x) ≡ μ x C.∘ μ (M₀ x)

Algebras over a monad🔗

One way of interpreting a monad $M$ is as giving a signature for an algebraic theory. For instance, the free monoid monad describes the signature for the theory of monoids, and the free group monad describes the theory of groups.

Under this light, an algebra over a monad is a way of evaluating the abstract operations given by a monadic expression to a concrete value. Formally, an algebra for $M$ is given by a choice of object $A$ and a morphism $ν : M (A) \to A .$

  record Algebra-on (M : Monad) (ob : C.Ob) : Type (o ⊔ h) where
    no-eta-equality
    open Monad M

    field
      ν : C.Hom (M₀ ob) ob

This morphism must satisfy equations categorifying those which define a monoid action. If we think of $M$ as specifying a signature of effects, then v-unit says that the unit has no effects, and v-mult says that, given two layers $M (M (A)),$ it doesn’t matter whether you first join then evaluate, or evaluate twice.

      ν-unit : ν C.∘ η ob ≡ C.id
      ν-mult : ν C.∘ M₁ ν ≡ ν C.∘ μ ob

Eilenberg-Moore category🔗

If we take a monad $M$ as the signature of an (algebraic) theory, and $M -algebras$ as giving models of that theory, then we can ask (like with everything in category theory): Are there maps between interpretations? The answer (as always!) is yes: An algebra homomorphism is a map of the underlying objects which “commutes with the algebras”.

We can be more specific about “commuting with the algebras” by drawing a square: A map $m : X \to Y$ in the ambient category is a homomorphism of $M -algebras$ when the square below commutes.

We can assemble $M -algebras$ and their homomorphisms into a displayed category over $C :$ the type of objects over some $A$ consists of all possible algebra structures on $A,$ and the type of morphisms over $f : C (A, B)$ are proofs that $f$ is an $M -algebra$ homomorphism.

  Monad-algebras : Displayed C (o ⊔ ℓ) ℓ
  Monad-algebras .Ob[_] X = Algebra-on C M X
  Monad-algebras .Hom[_] f α β = f C.∘ α .ν ≡ β .ν C.∘ M₁ f
  Monad-algebras .Hom[_]-set _ _ _ = hlevel 2

Defining the identity and composition maps is mostly an exercise in categorical yoga:

  Monad-algebras .id' {X} {α} =
    C.id C.∘ α .ν    ≡⟨ C.idl _ ∙ C.intror M-id ⟩
    α .ν C.∘ M₁ C.id ∎
  Monad-algebras ._∘'_ {_} {_} {_} {α} {β} {γ} {f = f} {g = g} p q =
    (f C.∘ g) C.∘ α .ν       ≡⟨ C.pullr q ⟩
    f C.∘ β .ν C.∘ M₁ g      ≡⟨ C.pulll p ⟩
    (γ .ν C.∘ M₁ f) C.∘ M₁ g ≡⟨ C.pullr (sym (M-∘ _ _)) ⟩
    γ .ν C.∘ M₁ (f C.∘ g)    ∎

The equations all hold trivially, as the type of displayed morphisms over

f

is a proposition.

  Monad-algebras .idr' _ = prop!
  Monad-algebras .idl' _ = prop!
  Monad-algebras .assoc' _ _ _ = prop!

The total category of this displayed category is referred to as the Eilenberg Moore category of $M .$

  Eilenberg-Moore : Precategory (o ⊔ ℓ) ℓ
  Eilenberg-Moore = ∫ Monad-algebras

  private
    module EM = Cat.Reasoning Eilenberg-Moore

  Algebra : Type _
  Algebra = EM.Ob

  Algebra-hom : (X Y : Algebra) → Type _
  Algebra-hom X Y = EM.Hom X Y

By projecting the underlying object of the algebras, and the underlying morphisms of the homomorphisms between them, we can define a functor from Eilenberg-Moore back to the underlying category:

  Forget-EM : Functor (Eilenberg-Moore M) C
  Forget-EM = πᶠ (Monad-algebras M)

This functor is faithful as the maps in the Eilenberg-Moore category are structured maps of $C .$

  Forget-EM-is-faithful : is-faithful Forget-EM
  Forget-EM-is-faithful = ext

Moreover, this functor is conservative. This follows from a bit of routine algebra.

  Forget-EM-is-conservative : is-conservative Forget-EM
  Forget-EM-is-conservative {X , α} {Y , β} {f = f} f-inv =
    EM.make-invertible f-alg-inv (ext invl) (ext invr)
    where
      open C.is-invertible f-inv

      f-alg-inv : Algebra-hom M (Y , β) (X , α)
      f-alg-inv .hom = inv
      f-alg-inv .preserves =
        inv C.∘ β .ν                                 ≡⟨ ap₂ C._∘_ refl (C.intror (MR.annihilate invl)) ⟩
        inv C.∘ β .ν C.∘ M₁ (f .hom) C.∘ M.M₁ inv    ≡⟨ ap₂ C._∘_ refl (C.extendl (sym (f .preserves))) ⟩
        inv C.∘ f .hom C.∘ α .ν C.∘ M.M₁ inv         ≡⟨ C.cancell invr ⟩
        α .ν C.∘ M₁ inv                              ∎

Univalence🔗

The displayed category of monad algebras is a displayed univalent category. This is relatively straightforward to show: first, note that the type of displayed isomorphisms must be a proposition. Next, we can perform a bit of simple algebra to show that the actions of two isomorphic $M -algebras$ are, in fact, equal.

  Monad-algebras-is-category : is-category-displayed (Monad-algebras M)
  Monad-algebras-is-category f α (β , p) (γ , q) =
    Σ-prop-path (λ _ _ _ → ext prop!) $ ext $
      β .ν                         ≡⟨ C.introl invl ⟩
      (to C.∘ from) C.∘ β .ν       ≡⟨ C.pullr (p .from') ⟩
      to C.∘ α .ν C.∘ M₁ from      ≡⟨ C.pulll (q .to') ⟩
      (γ .ν C.∘ M₁ to) C.∘ M₁ from ≡⟨ MR.cancelr invl ⟩
      γ .ν                         ∎
    where
      open C._≅_ f
      open Cat.Displayed.Morphism (Monad-algebras M)

By univalence of total categories, we can immediately deduce that the Eilenberg-Moore category inherits univalence from the base category.

  EM-is-category : is-category C → is-category (Eilenberg-Moore M)
  EM-is-category cat =
    is-category-total (Monad-algebras M) cat Monad-algebras-is-category

Free algebras🔗

In exactly the same way that we may construct a free group by taking the inhabitants of some set $X$ as generating the “words” of a group, we can, given an object $A$ of the underlying category, build a free $M -algebra$ on $A .$ Keeping with our interpretation of monads as logical signatures, this is the syntactic model of $M,$ with a set of “neutrals” chosen from the object $A .$

This construction is a lot simpler to do in generality than in any specific case: We can always turn $A$ into an $M -algebra$ by taking the underlying object to be $M (A),$ and the algebra map to be the monadic multiplication; The associativity and unit laws of the monad itself become those of the $M -action.$

  Free-EM : Functor C (Eilenberg-Moore M)
  Free-EM .F₀ A .fst = M₀ A
  Free-EM .F₀ A .snd .ν = μ A
  Free-EM .F₀ A .snd .ν-mult = mult-assoc
  Free-EM .F₀ A .snd .ν-unit = right-ident

The construction of free $M -algebras$ is furthermore functorial on the underlying objects; Since the monadic multiplication is a natural transformation $M \circ M \Rightarrow M,$ the naturality condition (drawn below) doubles as showing that the functorial action of $M$ can be taken as an algebraic action:

  Free-EM .F₁ f .hom = M₁ f
  Free-EM .F₁ f .preserves = sym $ mult.is-natural _ _ _
  Free-EM .F-id = ext M-id
  Free-EM .F-∘ f g = ext (M-∘ f g)

This is a free construction in the precise sense of the word: it’s the left adjoint to the functor Forget-EM, so in particular it provides a systematic, universal way of mapping from $C$ to $C^{M} .$

  open _⊣_

  Free-EM⊣Forget-EM : Free-EM ⊣ Forget-EM
  Free-EM⊣Forget-EM .unit =
    NT M.η M.unit.is-natural
  Free-EM⊣Forget-EM .counit =
    NT (λ x → total-hom (x .snd .ν) (sym (x .snd .ν-mult)))
      (λ x y f → ext (sym (f .preserves)))
  Free-EM⊣Forget-EM .zig = ext left-ident
  Free-EM⊣Forget-EM .zag {x} = x .snd .ν-unit

The full subcategory of free $M -algebras$ is often referred to as the Kleisli category of $M .$

  Kleisli : Precategory (o ⊔ ℓ) ℓ
  Kleisli = Essential-image (Free-EM {M = M})

If $C$ is univalent then so is the Kleisli category as it is a full subcategory of a univalent category.

  Kleisli-is-category : is-category C → is-category (Kleisli M)
  Kleisli-is-category cat = Essential-image-is-category Free-EM
    (EM-is-category cat)

As the Kleisli category is a full subcategory, there is a canonical full inclusion into the Eilenberg-Moore category.

  Kleisli→EM : Functor (Kleisli M) (Eilenberg-Moore M)
  Kleisli→EM = Forget-full-subcat

  Kleisli→EM-is-ff : is-fully-faithful Kleisli→EM
  Kleisli→EM-is-ff = id-equiv

Additionally, the free/forgetful adjunction between $C$ and the Eilenberg-Moore category can be restricted to the Kleisli category.

  Forget-Kleisli : Functor (Kleisli M) C
  Forget-Kleisli = Forget-EM F∘ Kleisli→EM

  Free-Kleisli : Functor C (Kleisli M)
  Free-Kleisli = Essential-inc Free-EM

  Free-Kleisli⊣Forget-Kleisli : Free-Kleisli ⊣ Forget-Kleisli
  Free-Kleisli⊣Forget-Kleisli ._⊣_.unit ._=>_.η = η
  Free-Kleisli⊣Forget-Kleisli ._⊣_.unit .is-natural = unit.is-natural
  Free-Kleisli⊣Forget-Kleisli ._⊣_.counit ._=>_.η ((X , α) , free) =
    total-hom (α .ν) (sym (α .ν-mult))
  Free-Kleisli⊣Forget-Kleisli ._⊣_.counit .is-natural _ _ f =
    ext (sym (f .preserves))
  Free-Kleisli⊣Forget-Kleisli ._⊣_.zig =
    ext left-ident
  Free-Kleisli⊣Forget-Kleisli ._⊣_.zag {(X , α) , free} =
    α . ν-unit

Note that the forgetful functor from the Kleisli category of $M$ to $C$ is also faithful and conservative.

  Forget-Kleisli-is-faithful : is-faithful Forget-Kleisli
  Forget-Kleisli-is-faithful = Forget-EM-is-faithful

  Forget-Kleisli-is-conservative : is-conservative Forget-Kleisli
  Forget-Kleisli-is-conservative f-inv =
    super-inv→sub-inv _ $
    Forget-EM-is-conservative f-inv