module Cat.Univalent.Rezk where

The Rezk completion🔗

In the same way that we can freely complete a proset into a poset, it is possible to, in a universal way, replace any precategory $A$ by a category $A,$ such that there is a weak equivalence (a fully faithful, essentially surjective functor) $A \to A,$ such that any map from $A$ to a univalent category $C$ factors uniquely through $A .$

The construction is essentially piecing together a handful of pre-existing results: The univalence principle for $n -types$ implies that Sets is a univalent category, and functor categories with univalent codomain are univalent; The Yoneda lemma implies that any precategory $A$ admits a full inclusion into $[A^{op}, Sets],$ and full subcategories of univalent categories are univalent — so, like Grothendieck cracking the nut, the sea of theory has risen to the point where our result is trivial:

module Rezk-large (A : Precategory o h) where
  Rezk-completion : Precategory (o ⊔ lsuc h) (o ⊔ h)
  Rezk-completion = Full-inclusion→Full-subcat {F = よ A} (よ-is-fully-faithful A)

  Rezk-completion-is-category : is-category Rezk-completion
  Rezk-completion-is-category =
    Restrict-is-category _ (λ _ → squash)
      (Functor-is-category Sets-is-category)

  Complete : Functor A Rezk-completion
  Complete = Ff-domain→Full-subcat {F = よ A} (よ-is-fully-faithful A)

  Complete-is-ff : is-fully-faithful Complete
  Complete-is-ff = is-fully-faithful-domain→Full-subcat
      {F = よ _} (よ-is-fully-faithful _)

  Complete-is-eso : is-eso Complete
  Complete-is-eso = is-eso-domain→Full-subcat {F = よ _} (よ-is-fully-faithful _)

However, this construction is a bit disappointing, because we’ve had to pass to a larger universe than the one we started with. If originally we had $A$ with objects living in a universe $o$ and homs in $h,$ we now have $A$ with objects living in $o ⊔ (1 + h) .$

It’s unavoidable that the objects in $A$ will live in an universe $o$ satisfying $(o ⊔ h) \leq o,$ since we want their identity type to be equivalent to something living in $h,$ but going up a level is unfortunate. However, it’s also avoidable!

Since $PSh (A)$ is a category, isomorphism is an identity system on its objects, which lives at the level of its morphisms — $o ⊔ h$ — rather than of its objects, $o ⊔ (1 + h) .$ Therefore, using the construction of small images, we may take $im よ_{A}$ to be a $o ⊔ h -type!$

module _ (A : Precategory o h) where
  private
    PSh[A] = PSh h A
    module PSh[A] = Precategory PSh[A]

    PSh[A]-is-cat : is-category PSh[A]
    PSh[A]-is-cat = Functor-is-category Sets-is-category

    module よim = Replacement PSh[A]-is-cat (よ₀ A)

  Rezk-completion : Precategory (o ⊔ h) (o ⊔ h)
  Rezk-completion .Ob          = よim.Image
  Rezk-completion .Hom x y     = よim.embed x => よim.embed y
  Rezk-completion .Hom-set _ _ = PSh[A].Hom-set _ _
  Rezk-completion .id    = PSh[A].id
  Rezk-completion ._∘_   = PSh[A]._∘_
  Rezk-completion .idr   = PSh[A].idr
  Rezk-completion .idl   = PSh[A].idl
  Rezk-completion .assoc = PSh[A].assoc

Our resized Rezk completion $A$ factors the Yoneda embedding $よ_{A}$ as a functor

A \sim A ↪ PSh (A)

where the first functor is a weak equivalence, and the second functor is fully faithful. Let’s first define the functors:

  complete : Functor A Rezk-completion
  complete .F₀   = よim.inc
  complete .F₁   = よ A .F₁
  complete .F-id = よ A .F-id
  complete .F-∘  = よ A .F-∘

  Rezk↪PSh : Functor Rezk-completion (PSh h A)
  Rezk↪PSh .F₀      = よim.embed
  Rezk↪PSh .F₁ f    = f
  Rezk↪PSh .F-id    = refl
  Rezk↪PSh .F-∘ _ _ = refl

From the existence of the second functor, we can piece together pre-existing lemmas about the image and about identity systems in general to show that this resized Rezk completion is also a category: We can pull back the identity system on $PSh (A)$ to one on $A,$ since we know of a (type-theoretic) embedding between their types of objects.

That gives us an identity system which is slightly off, that of “ $PSh (A) -isomorphisms$ on the image of the functor $A ↪ PSh (A)$ ”, but since we know that this functor is fully faithful, that’s equivalent to what we want.

  private module Rezk↪PSh = Ffr Rezk↪PSh id-equiv

  abstract
    Rezk-completion-is-category : is-category Rezk-completion
    Rezk-completion-is-category =
      transfer-identity-system
        (pullback-identity-system
          (Functor-is-category Sets-is-category)
          (よim.embed , よim.embed-is-embedding))
        (λ x y → Rezk↪PSh.iso-equiv e⁻¹)
        λ x → trivial!

It remains to show that the functor $A \to A$ is a weak equivalence. It’s fully faithful because the Yoneda embedding is, and it’s essentially surjective because it’s literally surjective-on-objects.

  complete-is-ff : is-fully-faithful complete
  complete-is-ff = よ-is-fully-faithful A

  complete-is-eso : is-eso complete
  complete-is-eso x = do
    t ← よim.inc-is-surjective x
    pure (t .fst , path→iso (t .snd))