module Cat.Displayed.GenericObject
  {o ℓ o' ℓ'} {B : Precategory o ℓ}
  (E : Displayed B o' ℓ')
  where

Generic objects🔗

There are 2 perspectives one can take on generic objects. The first is a purely logical one: generic objects provide us a tool for giving categorical models of higher order logics. The second perspective is that generic objects are a categorical way of describing the size of fibrations, and their ability to be internalized in the base category. We shall use both perspectives interchangeably!

With that caveat out of the way, we define a generic object to be some object $T : \mathcal{E}_{U}$ with the property that for any $X' : \mathcal{E}_{X}$, we have a (not necessarily unique) cartesian map $X' \to T$. Note that this means that generic objects are a structure in a fibration!

record Generic-object {t} (t' : Ob[ t ]) : Type (o ⊔ ℓ ⊔ o' ⊔ ℓ') where
  no-eta-equality
  field
    classify  : ∀ {x} → (x' : Ob[ x ]) → Hom x t
    classify' : ∀ {x} → (x' : Ob[ x ]) → Hom[ classify x' ] x' t'
    classify-cartesian : ∀ {x} (x' : Ob[ x ])
                       → is-cartesian E (classify x') (classify' x')

  module classify-cartesian {x} (x' : Ob[ x ]) = is-cartesian (classify-cartesian x')

The intuition for this definition is that if $\mathcal{E}$ has a generic object, then every object of $\mathcal{E}$ arises as a reindexing of $T$ along some morphism in the base.

If we think of $\mathcal{E}$ as some sort of logic over some syntactic category, then a generic object behaves like $\mathrm{Prop}$, the type of propositions. To see why, recall that an object $\mathcal{E}_{\Gamma}$ over a classifying category is a proposition in ranging over some free variables of type $\Gamma$. The classifying map in the base yields a substitution $\Gamma \to \mathrm{Prop}$, or in other words, a term of type $\mathrm{Prop}$ in context $\Gamma$. Furthermore, the classifying map upstairs gives an implication between the original proposition in $\mathcal{E}_{\Gamma}$ and a proof of the corresponding element of $\mathrm{Prop}$.

The size-based perspective on generic objects hinges on the fact that the family fibration on $\mathcal{C}$ has a generic object if and only if $\mathcal{C}$ is equivalent to a small, strict category. Fibred structure in the family fibration corresponds to structure in $\mathcal{C}$, so we can see the generic objects as a generalization of both a strictness and size condition.

With this size-based perspective in mind, we say that a displayed category is globally small if it has a generic object.

record Globally-small : Type (o ⊔ ℓ ⊔ o' ⊔ ℓ') where
  no-eta-equality
  field
    {U} : Ob
    Gen : Ob[ U ]
    has-generic-ob : Generic-object Gen

  open Generic-object has-generic-ob public

We can also prove the aforementioned characterisation in terms of base changes: If there exists an object $t' \mathrel{\htmlClass{liesover}{\hspace{1.366em}}} t$, such that, for every $x' \mathrel{\htmlClass{liesover}{\hspace{1.366em}}} x$, there is a map $u : x \to t$ exhibiting $x' \cong u^*(t')$ — then $t'$ is a generic object. The quantifier complexity of this sentence is a bit high, so please refer to the code:

  vertical-iso→Generic-object
    : ∀ {t} (t' : Ob[ t ])
    → (∀ {x} (x' : Ob[ x ])
      → Σ[ u ∈ Hom x t ]
         (base-change E fib u .F₀ t' ≅↓ x'))
    → Generic-object t'

Skeletal generic objects🔗

We say that a generic object $t'$ is skeletal if the classifying map in the base category is unique: if $u : x \to t$ underlies a Cartesian map $x' \to_u t'$, then it must be the map coming from the generic object structure of $t'$.

This condition is quite strong: for instance, the family fibration of a strict category $\mathcal{C}$ has a skeletal generic object if and only if $\mathcal{C}$ is skeletal.¹

is-skeletal-generic-object : ∀ {t} {t' : Ob[ t ]} → Generic-object t' → Type _
is-skeletal-generic-object {t} {t'} gobj =
  ∀ {x} {x' : Ob[ x ]} {u : Hom x t} {f' : Hom[ u ] x' t'}
  → is-cartesian E u f' → u ≡ classify x'
  where open Generic-object gobj

Gaunt generic objects🔗

A generic object is gaunt if the classifying maps themselves are unique. This condition expands on that of skeletality: if $u' : x' \to_u t'$ is a Cartesian map into the generic object $t'$, then not only must $u$ be generated by the structure we have equipped $t'$ with, but $u'$ must, as well.

We can also expand on what this means for the family fibration: $\mathrm{Fam}({\mathcal{C}})$ has a gaunt generic object if and only if $\mathcal{C}$ is itself gaunt (See here for the proof).

  field
    classify-unique : is-skeletal-generic-object gobj
    classify-unique'
      : ∀ {x} {x' : Ob[ x ]} {u : Hom x t} {f' : Hom[ u ] x' t'}
      → (cart : is-cartesian E u f')
      →  f' ≡[ classify-unique cart ] classify' x'